[tim_VV]

Hi,
my application is on a share, and users in the domain can run it from there.
But now, when they want to open my application, everytime a window pops up
asking the user whether they want to 'run' the application or not.
How can I get rid of this message?

This happens since last week, when some server stuff was changed. Before
that the message never popped up. So it must be possible to get rid of it,
but how?

Hope someone can help,
Tim

[Torgeir Bakken \(MVP\)]

tim_VV wrote:

> Hi,
> my application is on a share, and users in the domain can run
> it from there. But now, when they want to open my application,
> everytime a window pops up asking the user whether they want
> to 'run' the application or not.
> How can I get rid of this message?
>
> This happens since last week, when some server stuff was
> changed. Before that the message never popped up. So it must
> be possible to get rid of it, but how?
Hi,

You need to have the server that the drive points to, or, preferably,
the domain the server is in) defined as "Local intranet zone"

To see what zone you now have have for the path, in Explorer, select
"Status Bar" under the View menu. If it says "Internet", you will need
to add your server (or the domain) to the "Local intranet zone" in
Internet Explorer.

My suggestion (if this is an Active Directory domain):

Put in the DNS name for the domain (that you use in the FQDN mapping
string) in the Local Intranet zone, with a wildcard in front of it.
This solves the problem mentioned for us at least.

An example for the domain ad.fabrikam.com:

*.ad.fabrikam.com


Here is a VBScript that does the job for current user (that you can
e.g. put in a logon script):

'--------------------8<----------------------

SetCurrentAD2LocalIntranetZone


Sub SetCurrentAD2LocalIntranetZone()

' Set security zone to Local Intranet in Current user settings
' for AD Domain to avoid Internet zone for FQDN mappings.

Dim oShell, oADsSysInfo, aDomainDNSName, DomainNameSection
Dim sZoneDomainName, sZoneHostName

Set oShell = CreateObject("WScript.Shell")
Set oADsSysInfo = CreateObject("ADSystemInfo")

aDomainDNSName = Split(oADsSysInfo.DomainDNSName,".")
sZoneDomainName = ""
sZoneHostName = ""

For DomainNameSection = 0 To UBound(aDomainDNSName)

If DomainNameSection => (UBound(aDomainDNSName) - 1) Then

sZoneDomainName = sZoneDomainName _
& aDomainDNSName(DomainNameSection) & "."

Else
sZoneHostName = sZoneHostName _
& aDomainDNSName(DomainNameSection) & "."
End If
Next

sZoneDomainName = LCase(Left(sZoneDomainName, Len(sZoneDomainName) - 1))

If Right(sZoneHostName, 1) = "." Then
sZoneHostName = LCase("*." _
& Left(sZoneHostName, Len(sZoneHostName) - 1)) & "\*"
Else
sZoneHostName = "*"
End If

oShell.RegWrite "HKCU\Software\Microsoft\Windows\CurrentVersion" _
& "\Internet Settings\ZoneMap\Domains\" & sZoneDomainName & "\" _
& sZoneHostName, 1, "REG_DWORD"

End Sub

'--------------------8<----------------------



--
torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
Administration scripting examples and an ONLINE version of
the 1328 page Scripting Guide:
http://www.microsoft.com/technet/scriptcenter/default.mspx

[Anando [MS-MVP]]

>>when some server stuff was changed

What server OS are you running ? Windows Server 2003 ? Please post your question in the Windows
server 2003 groups.

--

Anando
Microsoft MVP- Windows Shell/User
http://www.microsoft.com/mvp
http://www.mvps.org

In memory of Alex Nichol
http://www.microsoft.com/windowsxp/expertzone/meetexperts/nichol.mspx

Folder customizations
http://newdelhi.sancharnet.in/minku

Protect your PC!
http://www.microsoft.com/protect


"tim_VV" <timVV@discussions.microsoft.com> wrote in message
news:C05B03DA-8F6E-4B14-9985-B93C313E23BB@microsoft.com...
> Hi,
> my application is on a share, and users in the domain can run it from there.
> But now, when they want to open my application, everytime a window pops up
> asking the user whether they want to 'run' the application or not.
> How can I get rid of this message?
>
> This happens since last week, when some server stuff was changed. Before
> that the message never popped up. So it must be possible to get rid of it,
> but how?
>
> Hope someone can help,
> Tim